Jump to content

EXTRACT TEXT OF SIDE (SEGEMENTS) FROM POLYGON

leo321

By leo321
in AutoLISP, Visual LISP & DCL

 Share

Recommended Posts

leo321 Contributor

leo321

Posted
Posted

Guys, as I show in the attached image,
If there is already a lisp that extracts the text from the polygon segment and generates a table or exports it to csv, on each side that contains text (each text will be inside a closed polygon).
use the sequence of the original vertex of the polygon as a reference.
I tried to find something similar but I couldn't find it.
Thanks for your help.

 

image.thumb.png.70d6425816a6109c4885d797809e93dc.png

image.thumb.png.0ac487682a4cb175fe02e6ca5c46eb97.png

Sampple side.dwgFetching info...

Lee Mac Grand Master

Lee Mac

Posted
Posted

A possible algorithm might be:

  1. Obtain set of vertex text (green text).
  2. Obtain set of region label text (red text).
  3. Obtain green polyline.
  4. Iterate over the set of polyline vertices and associate the green text content with each vertex by matching the text position with the vertex coordinates (so that the vertices can be labelled independently of their sequence in the polyline definition).
  5. For each red text object, call the BOUNDARY command to create a temporary boundary polyline using the text insertion point/alignment point as the internal point.
  6. Attempt to match the vertices of the boundary polyline with those of the green polyline and acquire the vertex numbers for all matches.
  7. Create a range from the matching vertex numbers.
  8. Delete the temporary boundary polyline.
  9. Continue until all red text objects have been processed.
  10. Sort the results by minimum vertex number in the vertex number range.
leo321 Contributor

leo321

Posted
  • Author
Posted

to minimize, you don't even need to count the vertexes, if you only have a list of the sequence of the sides following the original sequence in the polygon it would be enough.
this data will already be ready and nothing will be created (I refer to the texts), when the green numbering I left it just as an illustration but it doesn't even need to exist, because the reference will always be the vertexes of the polygon.

GLAVCVS Rising Star

GLAVCVS

Posted
Posted (edited)

Hi @leo321 
I suppose we can assume that the green text labels will always be within a proximity range less than their height from the vertex of the red polygon they refer to (2 drawing units).
Based on this premise and considering that your drawings will be of very limited dimensions, the algorithm could be somewhat simpler:


- Create a selection set for red polylines


- For each red polyline/polygon:
1) Obtain its list of points and run an ssget "_WP" just for the red text. Presumably, there will only be one text per set. If it's not the only one, you can apply a 'raycast' (Lee Mac) or an 'r4+' to check which of the two is the centroid.
2) Run an ssget "_C" with a window the size of the height of the green text, with each point in the polygon. If, in any case, more than one green text is selected, check which of the two is closest to the vertex. In either case, associate the selected green text with the polygon's centroid label using a list.


- Express the contents of the resulting association list through whatever means the user deems appropriate.

Edited by GLAVCVS
leo321 Contributor

leo321

Posted
  • Author
Posted (edited)

hi, @GLAVCVS
very interesting, I'll try something along these lines, thx for the tip,
This thinking is very reverse engineering style, nice

Edited by leo321
BIGAL Grand Master

BIGAL

Posted
Posted

Just another idea looking at the pattern of text and the pline offset the pline about a distance to get near text, then do a find text, raycast, little box etc. Not tested. You can match the 2 pline sections.

image.png.8b6e71b66849e4c47bf82f6e251a4b30.png

 

Saxlle Enthusiast

Saxlle

Posted
Posted (edited)

Hi @leo321,

 

I'v been played with this and made:

  

; *************************************************************************************
; Functions        :  TXTBL
; Subfunctions     :  -
; Description      :  Put the TEXT or MTEXT values into the tabel in model space
; Author           :  SAXLLE
; Date             :  April 03, 2025
; *************************************************************************************

(prompt "\nTo run a LISP type: TXTBL")
(princ)

(defun c:TXTBL ( / header first_column second_column ent ptlist len i pt_num pt_num_lst def_len len_pt_num_lst output_vertex output_text_val dist ang npt_one angn npt_second ss ssn
		len_ss j dist_pos_ent_name_lst n ent_ssn ptlist_ssn ss_new text_val_pos dist_pos dist_pos_ent_name dist_pos_ent_name_lst vertex text_val acadObj doc pt numRows numColumns
		rowHeight colWidth txtHeightHeader txtHeightColumns row col modelSpace myTable)
  
  (setq header "SEGEMENT"
	first_column "VERTEX"
	second_column "SIDE"
	)
  
  (prompt "\nSelect the GREEN Polyline:")
  
  (setq ent (ssget '((0 . "LINE,LWPOLYLINE") (8 . "LIXO") (62 . 3))))
  
  (setq ptlist (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 10)) (entget (ssname ent 0))))
	len (length ptlist)
	i 1
	)
  
  (foreach n ptlist
    
    (setq pt_num (cons i n)
	  pt_num_lst (cons pt_num pt_num_lst)
	  )
    
    (setq i (1+ i))
    )
  
  (setq pt_num_lst (reverse pt_num_lst))
  
  (setq def_len 250
	len_pt_num_lst (length pt_num_lst)
	i 0
	output_vertex (list)
	output_text_val (list)
	)
  
  (while (< i len_pt_num_lst)
    
    ;; start main if
    
    (if (not (equal (1+ i) len_pt_num_lst))
      
      ;; start main progn
      
      (progn
	
	(setq dist (/ (distance (cdr (nth i pt_num_lst)) (cdr (nth (1+ i) pt_num_lst))) 2)
	      ang (angle (cdr (nth i pt_num_lst)) (cdr (nth (1+ i) pt_num_lst)))
	      npt_one (polar (cdr (nth i pt_num_lst)) ang dist)
	      angn (+ ang (/ pi 2))
	      npt_second (polar npt_one angn def_len)
	      )
	
	(setq ss (ssget "_F" (list npt_one npt_second) '((0 . "TEXT,MTEXT") (8 . "LOTE"))))
	
	;; start cond
	
	(cond
	  
	  ;; 1. cond
	  
	  ((equal ss nil)
	   
	   (setq ssn (ssget "_F" (list npt_one npt_second) '((0 . "LWPOLYLINE") (8 . "LOTE")))
		 len_ss (sslength ssn)
		 j 0
		 dist_pos_ent_name_lst (list)
		 n (1- len_ss)
		 )
	   
	   (repeat len_ss
	     
	     ;; start if
	     
	     (if (not (equal n -1))
	       
	       ;; start progn
	       
	       (progn
		 
		 (setq ent_ssn (entget (ssname ssn n))
		       ptlist_ssn (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 10)) ent_ssn))
		       ss_new (ssget "_WP" ptlist_ssn '((0 . "TEXT,MTEXT") (8 . "LOTE")))
		       text_val_pos (cdr (assoc 10 (entget (ssname ss_new j))))
		       dist_pos (distance npt_one text_val_pos)
		       dist_pos_ent_name (list dist_pos (ssname ss_new j))
		       dist_pos_ent_name_lst (cons dist_pos_ent_name dist_pos_ent_name_lst)
		       n (1- n)
		       )
		 
		 ) ;; end progn
	       
	       ) ;; end if
	     
	     ) ;; end repeat
	   
	   (setq dist_pos_ent_name_lst (vl-sort dist_pos_ent_name_lst (function (lambda (x1 x2) (< (car x1) (car x2)))))) ;; Sorting list from MIN to MAX Distance with entity

	   (if (and (< (1+ i) 10) (< (+ i 2) 10))
	     
	     (setq vertex (strcat "0" (itoa (1+ i)) " - " "0" (itoa (+ i 2)))
		   text_val (cdr (assoc 1 (entget (car (cdr (nth j dist_pos_ent_name_lst))))))
		   output_vertex (cons vertex output_vertex)
		   output_text_val (cons text_val output_text_val)
		   )
	     
	     (setq vertex (strcat (itoa (1+ i)) " - " (itoa (+ i 2)))
		   text_val (cdr (assoc 1 (entget (car (cdr (nth j dist_pos_ent_name_lst))))))
		   output_vertex (cons vertex output_vertex)
		   output_text_val (cons text_val output_text_val)
		   )
	     )
	   
	   ) ;; end 1. cond
	  
	  ;; 2. cond
	  
	  ((not (equal ss nil))

	   (if (and (< (1+ i) 10) (< (+ i 2) 10))
	     
	   (setq vertex (strcat "0" (itoa (1+ i)) " - " "0" (itoa (+ i 2)))
		 text_val (cdr (assoc 1 (entget (ssname ss 0))))
		 output_vertex (cons vertex output_vertex)
		 output_text_val (cons text_val output_text_val)
		 )
	     
	     (setq vertex (strcat (itoa (1+ i)) " - " (itoa (+ i 2)))
		 text_val (cdr (assoc 1 (entget (ssname ss 0))))
		 output_vertex (cons vertex output_vertex)
		 output_text_val (cons text_val output_text_val)
		 )
	     )
	   
	   ) ;; end 2. cond
	  
	  ) ;; end cond
	
	) ;; end main progn
      
      ) ;; end main if
    
    (setq i (1+ i))
    
    ) ;; end while
  
  (setq last_i (1- i)
	i 0)
  
  ;; start repeat
  
  (repeat (1+ i)
    
    (setq dist (/ (distance (cdr (nth i pt_num_lst)) (cdr (nth last_i pt_num_lst))) 2)
	  ang (angle (cdr (nth last_i pt_num_lst)) (cdr (nth i pt_num_lst)))
	  npt_one (polar (cdr (nth last_i pt_num_lst)) ang dist)
	  angn (+ ang (/ pi 2))
	  npt_second (polar npt_one angn def_len)
	  )
    
    (setq ss (ssget "_F" (list npt_one npt_second) '((0 . "TEXT,MTEXT") (8 . "LOTE"))))
    
    ;; start cond
    
    (cond
      
      ;; 1. cond
      
      ((equal ss nil)
       
       (setq ssn (ssget "_F" (list npt_one npt_second) '((0 . "LWPOLYLINE") (8 . "LOTE")))
	     len_ss (sslength ssn)
	     j 0
	     dist_pos_ent_name_lst (list)
	     n (1- len_ss)
	     )
       
       (repeat len_ss
	 
	 ;; start if
	 
	 (if (not (equal n -1))
	   
	   ;; start progn
	   
	   (progn
	     
	     (setq ent_ssn (entget (ssname ssn n))
		   ptlist_ssn (mapcar 'cdr (vl-remove-if-not '(lambda (x) (= (car x) 10)) ent_ssn))
		   ss_new (ssget "_WP" ptlist_ssn '((0 . "TEXT,MTEXT") (8 . "LOTE")))
		   text_val_pos (cdr (assoc 10 (entget (ssname ss_new j))))
		   dist_pos (distance npt_one text_val_pos)
		   dist_pos_ent_name (list dist_pos (ssname ss_new j))
		   dist_pos_ent_name_lst (cons dist_pos_ent_name dist_pos_ent_name_lst)
		   n (1- n)
		   )
	     
	     ) ;; end progn
	   
	   ) ;; end if
	 
	 ) ;; end repeat
       
       (setq dist_pos_ent_name_lst (vl-sort dist_pos_ent_name_lst (function (lambda (x1 x2) (< (car x1) (car x2)))))) ;; Sorting list from MIN to MAX Distance with entity
       
       (setq vertex (strcat (itoa (+ last_i 1)) " - " "0" (itoa (+ i 1)))
	     text_val (cdr (assoc 1 (entget (car (cdr (nth j dist_pos_ent_name_lst))))))
	     output_vertex (cons vertex output_vertex)
	     output_text_val (cons text_val output_text_val)
	     )
       
       ) ;; end 1. cond
      
      ;; 2. cond
      
      ((not (equal ss nil))
       
       (setq vertex (strcat (itoa (+ last_i 1)) " - " "0" (itoa (+ i 1)))
	     text_val (cdr (assoc 1 (entget (ssname ss 0))))
	     output_vertex (cons vertex output_vertex)
	     output_text_val (cons text_val output_text_val)
	     )
       
       ) ;; end 2. cond
      
      ) ;; end cond
    
    ) ;; end repeat
  
  (setq output_vertex (reverse output_vertex))
  (setq output_text_val (reverse output_text_val))
  
  (setq acadObj (vlax-get-acad-object)
	doc (vla-get-ActiveDocument acadObj)
	)
  
  (if (= 1 (getvar 'cvport))
    (setvar 'ctab "MODEL")
    )
  
  (setq pt (vlax-3d-point (getpoint "\nPick the insertation point for Table:"))
	numRows (+ (length output_vertex) 2)
	numColumns 2
	rowHeight 14.00
	colWidth 100.0
	txtHeightHeader 7.50
	txtHeightColumns 5.00
	row 0
	col 0
	)
  
  (setq modelSpace (vla-get-ModelSpace doc))
  
  ;; Add a Header to Table
  
  (setq myTable (vla-Addtable modelSpace pt numRows numColumns rowHeight colWidth))

  ;; Put the color of the tabel into the Cyan
  
  (vla-put-Color myTable acCyan)
  
  (vla-SetTextHeight2 myTable row col row txtHeightHeader)
  (vla-SetColumnWidth myTable col colWidth)
  (vla-SetText myTable row col header)
  
  ;; Add a Header to 1. column
  
  (vla-SetTextHeight2 myTable (1+ row) col (1+ row) txtHeightColumns)
  (vla-SetColumnWidth myTable col (/ colWidth 2))
  (vla-SetText myTable (1+ row) col first_column)
  
  ;; Add a Header to 2. column
  
  (vla-SetTextHeight2 myTable (1+ row) (1+ col) (1+ row) txtHeightColumns)
  (vla-SetColumnWidth myTable (1+ col) (/ colWidth 2))
  (vla-SetText myTable (1+ row) (1+ col) second_column)
  
  ;; Iterate trought the "output_vertex" and add a value to every row at 1. column
  
  ;; while start
  
  (while (< row (length output_vertex))
    
    ;; start if
    
    (if (<= (1+ row) (length output_vertex))
      
      ;; progn start
      
      (progn
	
	(vla-SetTextHeight2 myTable (+ row 2) col (+ row 2) txtHeightColumns)
	(vla-SetCellAlignment myTable (+ row 2) col acMiddleCenter)
	(vla-SetText myTable (+ row 2) col (nth row output_vertex))
	
	) ;; progn end
      
      ) ;; if end
    
    (setq row (1+ row))
    
    ) ;; end while
  
  (setq row 0) ;; Reset the row number
  
  (setq col (1+ col)) ;; Go into the another column
  
  ;; Iterate trought the "output_text_val" and add a value to every row at 2. column
  
  ;; while start
  
  (while (< row (length output_text_val))
    
    ;; start if
    
    (if (<= (1+ row) (length output_text_val))
      
      ;; progn start
      
      (progn
	
	(vla-SetTextHeight2 myTable (+ row 2) col (+ row 2) txtHeightColumns)
	(vla-SetCellAlignment myTable (+ row 2) col acMiddleCenter)
	(vla-SetText myTable (+ row 2) col (nth row output_text_val))
	
	) ;; progn end
      
      ) ;; if end
    
    (setq row (1+ row))
    
    ) ;; end while
  
  (prompt "\nThe Tabel with values is inserted in model space!")
  (princ)
  )

 

As you can see on the picture from belowed, the "output tabel using lisp" is what I get using lisp from above, but there is one thing, when formatting "VERTEX" column, I get "9 - 10" insted of "09 - 10" (you can see the red rectangle). Also, it isn't formatted as yours "Your tabel" from picture (I'm not yet familiar with all things about the Tabel formatting, sorry 🫤). I didn't mention, I use this for "ssget" filter '((0 . "LINE,LWPOLYLINE") (8 . "LIXO") (62 . 3)))), '((0 . "TEXT,MTEXT") (8 . "LOTE")) and '((0 . "LWPOLYLINE") (8 . "LOTE")), if you have different layers names/colors, it wont work.

 

image.png.f6e40707e3a7b4d082df71df80c744b9.png

 

I hope it will helpful for your purpose. If you have maybe larger drawing, please upload it, just for the test.

 

Best regards.

Edited by Saxlle
  • Like 1
leo321 Contributor

leo321

Posted
  • Author
Posted

It turned out exactly as I wanted, I'm going to test it on other models.
I'll let you know if there's anything new.
Thank you very much

Saxlle Enthusiast

Saxlle

Posted
Posted

One pottentional issue can be occured when this line of code executed "(setq ent (ssget '((0 . "LINE,LWPOLYLINE") (8 . "LIXO") (62 . 3))))" and if you select many "green" lines, it will stop working. I tested it on "one by one" selecting, executing, place tabel and fill tabel with data, then re-run it and use it again.

Join the conversation

You can post now and register later. If you have an account, sign in now to post with your account.
Note: Your post will require moderator approval before it will be visible.

Guest
Unfortunately, your content contains terms that we do not allow. Please edit your content to remove the highlighted words below.
Reply to this topic...

×   Pasted as rich text.   Restore formatting

  Only 75 emoji are allowed.

×   Your link has been automatically embedded.   Display as a link instead

×   Your previous content has been restored.   Clear editor

×   You cannot paste images directly. Upload or insert images from URL.

×
 Share
Go to topic listing
×
×
  • Create New...