Transform selected texts into a table

[itacad]

Hello, I ask you if there is a way or do you know a lisp, that starting from a series of texts and multiline texts selected, generates an autocad table.
Thanks

[BIGAL]

There are a few examples out there that do what you want, but to comment properly need a dwg to look at.

 

There is some hiccups at times like missing text in a row.

Edited March 28 by BIGAL

[itacad]

Ok, I attach a simple file of a group of texts with different characteristics

Transform selected texts into a table.dwgFetching info...

[Saxlle]

Hi @itacad,

 

Try with this:

 

; *************************************************************************************
; Functions        :  SX:addTableInMS
; Subfunctions     :  -
; Description      :  Put the TEXT or MTEXT values into the tabel in model space
; Author           :  SAXLLE
; Date             :  March 31, 2025
; *************************************************************************************

(prompt "\nTo run a LISP type: SX:addTableInMS")
(princ)

(defun c:SX:addTableInMS ( / ss len i text_list text_val n acadObj doc pt numRows numColumns rowHeight colWidth txtHeight row col str_header modelSpace myTable)
  (setq ss (ssget '((0 . "*TEXT")))
	len (sslength ss)
	i 0
	text_list (list)
	)

  (while (< i len)
    
    (setq text_val (cdr (assoc 1 (entget (ssname ss i)))))

;;;    (if (equal (cdr (assoc 0 (entget (ssname ss i)))) "TEXT")
;;;      (setq text_val_new (LM:UnFormat nil text_val))
;;;      (setq text_val_new (LM:UnFormat T text_val))
;;;      )

    (setq text_list (cons text_val text_list))
	  
    (setq i (1+ i))
    )

  (setq colWidth (strlen (nth 0 text_list)))

  (repeat (setq n (length text_list))
    (setq n (1- n))
    (if (< colWidth (strlen (nth n text_list)))
      (setq colWidth (strlen (nth n text_list)))
      (setq colWidth colWidth)
      )
    )

  
  (setq acadObj (vlax-get-acad-object)
	doc (vla-get-ActiveDocument acadObj)
	)
  
  (if (= 1 (getvar 'cvport))
    (setvar 'ctab "MODEL")
    )
  
  (setq pt (vlax-3d-point (getpoint "\nPick the insertation point for Table:"))
        numRows (+ (length text_list) 1)
	numColumns (getint "\nEnter the number of columns:")
	rowHeight 3.00
;;;	colWidth 10.0
	txtHeight 2.50
	row 0
	col 0
	str_header "TEXT into the Table"
	)
  
  (setq modelSpace (vla-get-ModelSpace doc))
  
  ;;Add a Header to Table
  
  (setq myTable (vla-Addtable modelSpace pt numRows numColumns rowHeight (* colWidth 3)))
  
  (vla-SetTextHeight2 myTable row col row txtHeight)
  (vla-SetColumnWidth myTable col (* colWidth 3))
  (vla-SetText myTable row col str_header)

  ;; Iterate trought the "text_list" and add a value to every row

  ;; Outer while start
  
  (while (< col numColumns)

    ;; Iner while start
    
    (while (< row (length text_list))

      ;; start if
      (if (<= (1+ row) (length text_list))

	;; progn start
	(progn
	  (vla-SetTextHeight2 myTable (1+ row) col (1+ row) txtHeight)
	  (vla-SetCellAlignment myTable (1+ row) col acMiddleCenter)
	  (vla-SetText myTable (1+ row) col (nth row text_list))
	  ) ;; progn end
	
	) ;; if end
      
      (setq row (1+ row))
      
      ) ;; end iner while
    
    (setq row 0) ;; Reset the row number
    
    (setq col (1+ col)) ;; Go into the another column
    
    ) ;; end outer while
  
  (prompt "\nThe Tabel with values is inserted in model space!")
  (princ)
  )

 

The output will be like this

 

 

Best regards.

[itacad]

Hello and thank you in the meantime!
I did some tests and lisp does exactly what I need!
Thanks again

[Saxlle]

You're welcome