Accessing nested blocks objects

[p7q]

I'm trying to access all entities inside a selected block reference.
However, the block might contain nested blocks (blocks within blocks, and so on, potentially many levels deep).

I need a way to recursively get all the entities, including those inside nested blocks.

Could anyone help me with how to approach this or share a sample code snippet?

Thanks in advance!

[GLAVCVS]

 

https://www.cadtutor.net/forum/topic/96878-assign-color-to-a-block-and-its-nested-blocks/

[Lee Mac]

Here's a simple example -

(defun getblockentities ( blk / ent enx rtn )
    (if (setq ent (tblobjname "block" blk))
        (while (setq ent (entnext ent))
            (setq enx (entget ent))
            (if (= "INSERT" (cdr (assoc 0 enx)))
                (setq rtn (append (reverse (getblockentities (cdr (assoc 2 enx)))) rtn))
                (setq rtn (cons ent rtn))
            )
        )
    )
    (reverse rtn)
)

 

(getblockentities "YourBlock")

 

Edited March 27 by Lee Mac

[p7q]

 

  On 3/27/2025 at 11:55 AM, Lee Mac said:

Here's a simple example -

(defun getblockentities ( blk / ent enx rtn )
    (if (setq ent (tblobjname "block" blk))
        (while (setq ent (entnext ent))
            (setq enx (entget ent))
            (if (= "INSERT" (cdr (assoc 0 enx)))
                (setq rtn (append (reverse (getblockentities (cdr (assoc 2 enx)))) rtn))
                (setq rtn (cons ent rtn))
            )
        )
    )
    (reverse rtn)
)

 

(getblockentities "YourBlock")

 

Expand  

Thanks Lee for the sample function!

I noticed that this code retrieves only the entities inside the nested blocks, but it doesn't include the nested block references (INSERT entities) themselves.

For example, if my main block contains two nested blocks, and each of those has 3 entities inside, this function returns 6 entities — but I also need the two INSERT entities representing the nested blocks themselves.

So in total, I would expect 8 entities: 2 nested blocks (as INSERTs) + 6 entities inside them.

How can I modify the function to include the INSERTs (nested blocks) themselves as well?

Thanks again!

Edited March 27 by p7q

[Lee Mac]

I'll let you work that out

[p7q]

  On 3/27/2025 at 1:35 PM, Lee Mac said:

I'll let you work that out

Expand  

I made it  

(defun getblockentities (blk / ent enx rtn)
    (if	(setq ent (tblobjname "block" blk))
      (while (setq ent (entnext ent))
	(setq enx (entget ent))
	(if (= "INSERT" (cdr (assoc 0 enx)))
	  (progn
	    (setq rtn (cons ent rtn))	; INSERT objesini ekle
	    (setq rtn
		   (append
		     (reverse (getblockentities (cdr (assoc 2 enx))))
		     rtn
		   )
	    )
	  )
	  (setq rtn (cons ent rtn))	; Diğer nesneleri doğrudan ekle
	)
      )
    )
    (reverse rtn)
  )

Thanks Lee for encouragement.

[Lee Mac]

Well done 

 

An alternative would be to move (setq rtn (cons ent rtn)) outside of the if statement, e.g.:

(defun getblockentities ( blk / ent enx rtn )
    (if (setq ent (tblobjname "block" blk))
        (while (setq ent (entnext ent))
            (setq rtn (cons ent rtn)
                  enx (entget ent)
            )
            (if (= "INSERT" (cdr (assoc 0 enx)))
                (setq rtn (append (reverse (getblockentities (cdr (assoc 2 enx)))) rtn))
            )
        )
    )
    (reverse rtn)
)