xline to always be red????

[MikeP]

how can I set the construction lines to always come out as red. what do I need to enter in the macro in the CUI to do this?

[ReMark]

You would have to put your construction lines on a layer (Construction?) that has its layer color set to red as the default.

[MikeP]

You would have to put your construction lines on a layer (Construction?) that has its layer color set to red as the default.

 

 

how do I do that?

[Lee Mac]

You could always use a reactor to automatically switch to the correct layer when you use xline command:

 

(vl-load-com)
(if (not layer:reactor)
 (setq layer:reactor
        (vlr-command-reactor
          nil
          '((:vlr-commandWillstart . sCom)
            (:vlr-commandEnded . eCom)
            (:vlr-commandCancelled . cCom)))))

(or (tblsearch "LAYER" "CONSTRUCTION")
   (vla-put-Color
     (vla-add (vla-get-Layers
                (vla-get-ActiveDocument
                  (vlax-get-acad-object))) "CONSTRUCTION") acRed))

(defun sCom  (Reac Args)
 (setq oldlay (getvar 'CLAYER))
 (if (eq "XLINE" (car Args))
   (setvar 'CLAYER "CONSTRUCTION"))
 (princ))

(defun eCom  (Reac Args)
 (if (eq "XLINE" (car Args))
   (setvar 'CLAYER oldlay))
 (princ))

(defun cCom  (Reac Args)
 (if (eq "XLINE" (car Args))
   (setvar 'CLAYER oldlay))
 (princ))

 

Just put this in your ACADDOC.lsp or Start-up Suite

 

HTH

 

Lee

[Lee Mac]

Or, a simpler version to be used - perhaps in a macro button:

 

(or (not (tblsearch "LAYER" "CONSTRUCTION"))
   (setvar "CLAYER" "CONSTRUCTION"))
(command "_xline")
(while (> (getvar "CMDACTIVE") 0)
 (command pause))

[uddfl]

Something like this, assuming you use a layer called "CONSTRUCTION"

 

^C^C-LAYER M CONSTRUCTION C 1;  ;  ;  XLINE 

[MikeP]

this worked just perfect thanks

 

 

You could always use a reactor to automatically switch to the correct layer when you use xline command:

 

(vl-load-com)
(if (not layer:reactor)
 (setq layer:reactor
        (vlr-command-reactor
          nil
          '((:vlr-commandWillstart . sCom)
            (:vlr-commandEnded . eCom)
            (:vlr-commandCancelled . cCom)))))

(or (tblsearch "LAYER" "CONSTRUCTION")
   (vla-put-Color
     (vla-add (vla-get-Layers
                (vla-get-ActiveDocument
                  (vlax-get-acad-object))) "CONSTRUCTION") acRed))

(defun sCom  (Reac Args)
 (setq oldlay (getvar 'CLAYER))
 (if (eq "XLINE" (car Args))
   (setvar 'CLAYER "CONSTRUCTION"))
 (princ))

(defun eCom  (Reac Args)
 (if (eq "XLINE" (car Args))
   (setvar 'CLAYER oldlay))
 (princ))

(defun cCom  (Reac Args)
 (if (eq "XLINE" (car Args))
   (setvar 'CLAYER oldlay))
 (princ))

Just put this in your ACADDOC.lsp or Start-up Suite

 

HTH

 

Lee

[Lee Mac]

No probs Mike - happy to help out mate