radius dimension for the selected arcs

[m.alshboul]

Greets 
is there any lisp to find the radius dimension for selected arcs in one time?

[Lee Mac]

You can simply obtain DXF group 40 for the arcs, e.g.:

(defun c:test ( / i s )
    (if (setq s (ssget '((0 . "ARC"))))
        (repeat (setq i (sslength s))
            (princ (strcat "\nArc radius: " (rtos (cdr (assoc 40 (entget (ssname s (setq i (1- i)))))))))
        )
    )
    (princ)
)

 

[Nikon]

Lisp writes the values of the radii of the arcs in the command string, but how to make the dimensions of the arcs in

the drawing? Is it possible to add a circle as well?

 

 

Edited November 18, 2023 by Nikon

[BIGAL]

So circles exist, do dimensions Program 1 ?

No circles exist add circle and do dims, Program 2 ?

 

Explain more details please.

Edited November 19, 2023 by BIGAL

[Nikon]

Circles and arcs exist. Select all and get the radius of all in one time...

The result is as in the picture posted 11. 

[m.alshboul]

Thanks, Mr. Lee Mac, but as Mr. Nikon said I need to make the dimensions of the arcs, all arcs at one time, and when you add the circles the lisp will be more amazing.

[marko_ribar]

Untested...

 

(defun c:test ( / i s e )
    (if (setq s (ssget '((0 . "CIRCLE,ARC"))))
        (repeat (setq i (sslength s))
            (setq e (ssname s (setq i (1- i))))
            (vl-cmdf "_.DIMRAD" e (vlax-curve-getpointatdist e (/ (vlax-curve-getdistatparam e (vlax-curve-getendparam e)) 2.0))) 
        )
    )
    (princ)
)

 

Edited November 19, 2023 by marko_ribar

[m.alshboul]

not work

[Nikon]

Lisp works great! Thank you very much, @marko_ribar! Good luck!

Edited December 14, 2023 by Nikon

[Nikon]

m.alshboul

Specify the command for your version of AutoCAD, you may need to change "_.DIMRAD" to "_dimradius" or another variant.

[m.alshboul]

I have AutoCAD 2024, i don't know what I will do

[Nikon]

In AutoCAD, create a radius. At the command prompt, type r (Radius)

See in the command line how the Radius command is displayed, 
copy and paste into lisp instead of "_.DIMRAD" (perhaps  "DIMRADIUS")

(defun c:test ( / i s e ) 
(if (setq s (ssget '((0 . "CIRCLE,ARC")))) 
(repeat (setq i (sslength s)) (setq e (ssname s (setq i (1- i)))) 
(vl-cmdf "DIMRADIUS" e (vlax-curve-getpointatdist e (/ (vlax-curve-getdistatparam e (vlax-curve-getendparam e)) 2.0))) ) ) 
(princ) 
)

 

Edited November 19, 2023 by Nikon

[m.alshboul]

even this not work

[Nikon]

have you tried with this?  "_dimradius"

(defun c:test ( / i s e )
 (if (setq s (ssget '((0 . "CIRCLE,ARC"))))
 (repeat (setq i (sslength s))
 (setq e (ssname s (setq i (1- i))))
 (vl-cmdf "_dimradius" e (vlax-curve-getpointatdist e (/ (vlax-curve-getdistatparam e (vlax-curve-getendparam e)) 2.0))) 
 )
 )
 (princ)
)

 

[m.alshboul]

I bothered you with me, I'm really sorry but this doesn't work

[Nikon]

I have AutoCAD 2015 at home, tomorrow at work I will try it in AutoCAD 2020...
Or someone else will tell you...

[Tsuky]

And to test, if you copy and paste this code directly into the command line?

((lambda ( / ent dxf_ent)
  (while (not (eq ent "eXit"))
    (initget "eXit")
    (while (null (setq ent (entsel "\nSelect an arc or a circle to dim, [eXit] for quit: "))) (initget "eXit"))
    (if (/= ent "eXit")
      (progn
        (setvar "cmdecho" 0)
        (setq dxf_ent (entget (car ent)))
        (cond
          ((eq (cdr (assoc 0 dxf_ent)) "ARC")
            (command "_.dimradius" (cadr ent) "")
          )
          ((eq (cdr (assoc 0 dxf_ent)) "CIRCLE")
            (command "_.dimdiameter" (cadr ent) "")
          )
          (T
            (princ "\nIsn't an arc or circle!")
          )
        )
        (setvar "cmdecho" 1)
      )
    )
  )
  (prin1)
))

 

[BIGAL]

TSUKY does not work in Bricscad V20.

 

(command "_.dimdiameter" (cadr ent) "")

 _.dimdiameter
Select arc or circle to dimension:
Opposite Corner: 
Invalid window specified.
Opposite Corner: nil
Opposite Corner: 
Cancel

 

NIKON works needs tuning to suit dim style etc, minor issue dwg dependant.

 

[Nikon]

The Tsuky code works in AutoCAD 2020 (Only selects not all objects, but one object),

and what needs to be added to make a full-fledged lisp
(defun c:test...???

Edited November 20, 2023 by Nikon

[m.alshboul]

thanks Bigal, but this not working as me want