Help - Scale about Center by a Specific Value

[barristann]

Hi all,
Is it possible to modify this Lee Mac code, to always Scale up by 2 (instead of having the user to enter a value)? Thank you.

 

https://www.cadtutor.net/forum/topic/38409-looking-for-a-lisp-which-scale-objects-with-its-own-center-point/

 

;; Scale About Center - Lee Mac

(defun c:sac ( / ll sel obj ur )
   (initget 6)
   (if
       (and
           (setq *scl*
               (cond
                   (   (getdist (strcat "\nSpecify Scale Factor" (if *scl* (strcat " <" (rtos *scl* 2) ">: ") ": "))))
                   (   *scl*   )
               )
           )
           (ssget "_:L")
       )
       (progn
           (vlax-for obj (setq sel (vla-get-activeselectionset (vla-get-activedocument (vlax-get-acad-object))))
               (if (null (vl-catch-all-error-p (vl-catch-all-apply 'vla-getboundingbox (list obj 'll 'ur))))
                   (vla-scaleentity obj
                       (vlax-3D-point
                           (mapcar '(lambda ( a b ) (/ (+ a b) 2.0))
                               (vlax-safearray->list ll)
                               (vlax-safearray->list ur)
                           )
                       )
                       *scl*
                   )
               )
           )
           (vla-delete sel)
       )
   )
   (princ)
)
(vl-load-com) (princ)

Edited January 25, 2023 by barristann

[ronjonp]

Try this mod:
 

;; Scale About Center - Lee Mac

(defun c:sac ( / ll sel obj scl ur )
   (if
       (and
           (setq scl
               2
           )
           (ssget "_:L")
       )
       (progn
           (vlax-for obj (setq sel (vla-get-activeselectionset (vla-get-activedocument (vlax-get-acad-object))))
               (if (null (vl-catch-all-error-p (vl-catch-all-apply 'vla-getboundingbox (list obj 'll 'ur))))
                   (vla-scaleentity obj
                       (vlax-3D-point
                           (mapcar '(lambda ( a b ) (/ (+ a b) 2.0))
                               (vlax-safearray->list ll)
                               (vlax-safearray->list ur)
                           )
                       )
                       scl
                   )
               )
           )
           (vla-delete sel)
       )
   )
   (princ)
)
(vl-load-com) (princ)

 

[barristann]

You are amazing ronjonp! It works wonders! Thank you ronjonp.

[ronjonp]

12 hours ago, barristann said:

You are amazing ronjonp! It works wonders! Thank you ronjonp.

Glad to help.