Match rotate angel to another block

[sivapathasunderam]

Lisp to match rotation angel to another block (first click on a block that rotation pick then another click on another block apply)

[ronjonp]

This has nothing to do with a higher power, but it will match the ANGLE of a picked block to a selection. 

(defun c:foo (/ a e s)
  (if (and (setq e (car (entsel "\nPick a block to match rotation: ")))
	   (setq a (cdr (assoc 50 (entget e))))
	   (setq s (ssget ":L" '((0 . "INSERT"))))
      )
    (foreach e (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
      (vla-put-rotation (vlax-ename->vla-object e) a)
    )
  )
  (princ)
)

 

[tombu]

I've used this code by alanjt for many years. Works on Text, Blocks, or Hatch with options.

Copyright© March 2009
    Alan J. Thompson (alanjt)
   https://www.theswamp.org/index.php?topic=40450.0

RotateObjects.LSP

Edited April 21, 2021 by tombu

[sivapathasunderam]

@ronjonp & @tombu

 

many thanks to both of you and your valuable contributions ... both of your suggestions work perfectly !

 

thanks again

[ronjonp]

8 minutes ago, sivapathasunderam said:

@ronjonp & @tombu

 

many thanks to both of you and your valuable contributions ... both of your suggestions work perfectly !

 

thanks again

Glad to help 

 

Here is a version to rotate all objects with a rotation property:

(defun c:foo (/ a e o s)
  (if (and (setq e (car (entsel "\nPick something to match rotation: ")))
	   (setq a (cdr (assoc 50 (entget e))))
	   (setq s (ssget ":L"))
      )
    (foreach e (vl-remove-if 'listp (mapcar 'cadr (ssnamex s)))
      (if (vlax-property-available-p (setq o (vlax-ename->vla-object e)) 'rotation)
	(vla-put-rotation o a)
      )
    )
  )
  (princ)
)