Select all polylines of certain layer and fillet them ?

[John Camper]

How to select all polylines of certain layer(Eg: "Walls") and fillet them with (0.25) radius .I am just new at this lisp scene so any help would be appreciated.Below is the separate code that selects all elements of layer and  another code fillets all selected polylines.How can i combine these two to create a single lisp for certain layer("walls") and (0.25) fillet.

(defun c:SALL ()
 (setq TargEnt (car (entsel "\nSelect object on layer to select: ")))
 (setq TargLayer (assoc 8 (entget TargEnt)))
 (sssetfirst nil (ssget "_X" (list TargLayer)))
 (princ)
)


(defun C:FMP ; = Fillet Multiple Polylines
  (/ plss n)
  (if (setq plss (ssget "_:L" '((0 . "LWPOLYLINE"))))
    (repeat (setq n (sslength plss))
      (command "_.fillet" "_polyline" (ssname plss (setq n (1- n))))
    ); repeat
  ); if
  (princ)
); defun

 

[hosneyalaa]

;;;https://www.theswamp.org/index.php?topic=56258.0
;; @Tharwat
(defun c:Test (/ int sel ent)
  (and
    (or (/= 4
            (logand 4
                    (cdr (assoc 70 (entget (tblobjname "LAYER" "wall"))))
            )
        )
        (alert "Layer name <wall> is locked ! unlock then try again"
        )
    )
    (setq int -1
          sel (ssget "_X"
                     (list '(0 . "LWPOLYLINE")
                           '(8 . "wall")
                           (cons 410 (getvar 'CTAB))
                     )
              )
    )
    (setvar 'FILLETRAD 0.25)
    (while (setq int (1+ int)
                 ent (ssname sel int)
           )
      (command "_.FILLET" "_Polyline" ent)
    )
  )
  (princ)
)