Remove spaces from string

[Jonathan Handojo]

Hi all,

 

Does anyone have a function quite very similar to the trim command of a string that allows you to remove multiple spaces into just one.

 

For example, if you function is

(defun RemoveGaps (str / ;|your local variables|;)
    ; your function
    )

 

Then running (RemoveGaps "   This            is          a   normal         string.      ") will return "This is a normal string."

 

Thanks

Jonathan Handojo

 

Edited July 14, 2020 by Jonathan Handojo

[BIGAL]

Just loop it look for 2 spaces replace with 1. Once wcmatch "  " not found do next string. Also need the "\n" and "\t" so removes spaces at start. 

 

From help

Substitutes one string for another, within a string

(vl-string-subst new-str pattern string [start-pos])

 

(setq str " Leave   me    alone ")

Command: (setq str (vl-string-subst " " "  " str 1))
" Leave  me    alone "
Command: (setq str (vl-string-subst " " "  " str 1))
" Leave me    alone "
Command: (setq str (vl-string-subst " " "  " str 1))
" Leave me   alone "
Command: (setq str (vl-string-subst " " "  " str 1))
" Leave me  alone "
Command: (setq str (vl-string-subst " " "  " str 1))
" Leave me alone "

Check if 1st character is " " and last is " "

"Leave me alone"
 

Edited July 14, 2020 by BIGAL

[Jonathan Handojo]

Haha, how stupid of me. Thanks for that hint BIGAL.

 

I suppose for \n and \t, can always do (vl-string-translate "\n\t" "  " str) first before executing your above code.

Edited July 14, 2020 by Jonathan Handojo

[BIGAL]

No worries I am sure someone will do a smart lambda function.

[Tharwat]

Here is one way without the use of converting string to list then list to string and without the use of lambda.  

(defun weed:out:spaces ( s / n c g) (setq n "")
  ;; Tharwat - 14.Jul.2020	;;
  (while (/= "" (setq c (substr s 1 1)))
    (or (= g c " ") (setq n (strcat n c)))
    (setq g c s (substr s 2))
    )
  (vl-string-trim " " n)
  )

 

Edited July 14, 2020 by Tharwat

[Jonathan Handojo]

Thanks Tharwat. After hearing BIGAL's suggestion, I've come to deduce it to:

 

(defun RemoveGaps (str)
    (while (/= str (setq str (vl-string-subst " " "  " str))))
    (vl-string-trim " " str)
    )

 

Edited July 14, 2020 by Jonathan Handojo
'left & right trim' to just 'trim'

[Tharwat]

You're welcome Jonathan.

Please note that you can replace the two trim functions left & right with one as I demonstrated earlier in my codes with vl-string-trim

[Jonathan Handojo]

Ohh, right. Nice. Modified that one

[hanhphuc]

 

 

(setq $ (strcase (vl-princ-to-string (read "(   This            is          a   normal         string.      )")) t))
(substr $ 2 (- (strlen $) 2))

hiccups strcase

 

 

[dlanorh]

(defun rh:rss (str) (while (vl-string-search "  " str) (setq str (vl-string-subst " " "  " str))) (vl-string-trim " " str))

 

[pBe]

(defun _LostInSpace (str / p)
  (setq str (vl-string-trim " " str))
  ((lambda (s)
     (while (setq p (vl-string-position
		      32
		      str
		    )
	    )
       (setq s	 (strcat s (substr str 1 p) " ")
	     str (vl-string-trim " " (substr str (1+ p)))
       )
     )
     (strcat s str)
   )
    ""
  )
)

 

[dlanorh]

1 hour ago, pBe said:

(defun _LostInSpace (str / p)

 

 

 

Danger! Will Robinson

 

[pBe]

1 hour ago, dlanorh said:

Danger! Will Robinson

 

 

That's the classic Robot. [ the nice one ]

 

But this is the baddie.. [ 1998 ]

Destroy the Robinsons family!!! 

 

[ronjonp]

Another for fun

(defun _lostinspace2 (str / p)
  (apply 'strcat (mapcar '(lambda (s) (if (= 32 s) "" (chr s)))(vl-string->list str)))
)
(_lostinspace2 "this is a test of the radio  broadcast     system")
;;"thisisatestoftheradiobroadcastsystem" 

Oops .. read the title too literally.  .. this just removes all spaces.

Edited July 15, 2020 by ronjonp
*code does not meet the requirement

[hanhphuc]

 

 

(defun foo (x l)
  (if l
    (vl-remove nil (cons (if (not (= x (car l) (cadr l))) (car l)) (foo x (cdr l))))
  )
)

(defun ?_? (str)
  (vl-string-trim " "
                  (vl-list->string
                    (foo 32 (vl-string->list str))
                  )
  )
)

 

 

4 hours ago, pBe said:

_LostInSpace 

 

 Mayday oxygen

 

 

[Stefan BMR]

Another one

(defun disspacify (str / regexp)
  (if
    (setq regexp (vlax-get-or-create-object "vbscript.regexp"))
    (progn
      (vlax-put-property regexp 'global actrue)
      (vlax-put-property regexp 'pattern " +")
      (vlax-invoke regexp 'replace (vl-string-trim " " str) " ")
    )
  )
)

_$ (disspacify "   This            is          a   normal         string.      ")
"This is a normal string."
_$ 

[Edit]: Why not full regular expression... Plus, the dot or comma inside the string needs special treatment:

(defun disspacify (str / regexp)
  (if
    (setq regexp (vlax-get-or-create-object "vbscript.regexp"))
    (progn
      (vlax-put-property regexp 'global actrue)
      (foreach x '(
                    (" +[.]|[.]" . ". ");"end ."  to "end. "
                    (" +[,]|[,]" . ", ");"mid ,"  to "mid, "
                    (" +"        .  " ");replace multiple spaces
                    ("^ +| +$"   .   "");remove start and end space(s)
                  )
        (vlax-put-property regexp 'pattern (car x))
        (setq str (vlax-invoke regexp 'replace str (cdr x)))
      )  
    )
  )
)

_$ (disspacify "   This   is   a double     sentence ,the   other   one    is     not    .This   is   a   normal      string  .      ")
"This is a double sentence, the other one is not. This is a normal string."
_$ 

 

Edited July 14, 2020 by Stefan BMR

[BIGAL]

Who thought a simple find replace request could end up with so many different versions.

[Jonathan Handojo]

2 hours ago, Stefan BMR said:

Another one

(defun disspacify (str / regexp)
  (if
    (setq regexp (vlax-get-or-create-object "vbscript.regexp"))
    (progn
      (vlax-put-property regexp 'global actrue)
      (vlax-put-property regexp 'pattern " +")
      (vlax-invoke regexp 'replace (vl-string-trim " " str) " ")
    )
  )
)

_$ (disspacify "   This            is          a   normal         string.      ")
"This is a normal string."
_$ 

[Edit]: Why not full regular expression... Plus, the dot or comma inside the string needs special treatment:

(defun disspacify (str / regexp)
  (if
    (setq regexp (vlax-get-or-create-object "vbscript.regexp"))
    (progn
      (vlax-put-property regexp 'global actrue)
      (foreach x '(
                    (" +[.]|[.]" . ". ");"end ."  to "end. "
                    (" +[,]|[,]" . ", ");"mid ,"  to "mid, "
                    (" +"        .  " ");replace multiple spaces
                    ("^ +| +$"   .   "");remove start and end space(s)
                  )
        (vlax-put-property regexp 'pattern (car x))
        (setq str (vlax-invoke regexp 'replace str (cdr x)))
      )  
    )
  )
)

_$ (disspacify "   This   is   a double     sentence ,the   other   one    is     not    .This   is   a   normal      string  .      ")
"This is a double sentence, the other one is not. This is a normal string."
_$ 

 

 

Well, I'm only needing it for one sentence, and one consisting of letters. Otherwise you've got a lot more punctuations to consider other than just dots and commas...

 

" I      spent   $   2  .  00      on      ice    -    cream .  "

[Stefan BMR]

15 minutes ago, Jonathan Handojo said:

 

Well, I'm only needing it for one sentence, and one consisting of letters. Otherwise you've got a lot more punctuations to consider other than just dots and commas...

 

" I      spent   $   2  .  00      on      ice    -    cream .  "

 

You're right, I opened Pandora's box and now I can't handle it, sorry for that.

[Jonathan Handojo]

3 hours ago, Stefan BMR said:

 

You're right, I opened Pandora's box and now I can't handle it, sorry for that.

 

Maybe someone will be able to close it. I don't need it to be closed though, the solutions offered here are good enough for me.