how to change a color of a line previusly drawn with Autolispp

[danyra]

Im a begginer, I drawn a line in autolisp with this "code":

 

(setq p1 (getpoint "\nPunto Inicial:"))
      (setq p2 (polar p1 (* 1.5 pi) 0.18))
        (command "line" p1 p2 "")
  

but, how can I change the color of this line?? For example I want yellow

Thanks for your help.

Edited December 2, 2019 by danyra

[rkmcswain]

1. You could change your current layer to a layer that is yellow before creating the line.
2. You could use (entmake) instead of (command) and set the color during creation time. (sample below)
3. You could run (command "._change) after (command ._line") and change the color of (entlast) to yellow, or move it to a yellow layer.

 

(setq p1 (getpoint "\nPunto Inicial:"))
(setq p2 (polar p1 (* 1.5 pi) 0.18))
(entmake
  (list
    (cons 0 "LINE")
    (cons 8 "0")
    (cons 62 2)
    (cons 10 p1)
    (cons 11 p2)
  )
)

 

[ronjonp]

As @rkmcswain mentioned you could do something like so:

(if (setq p1 (getpoint "\nPunto Inicial:"))
  (progn (setq p2 (polar p1 (* 1.5 pi) 0.18))
	 ;; (command "line" p1 p2 "")
	 (entmakex (list '(0 . "line") (cons 10 p1) (cons 11 p2) '(62 . 2)))
  )
)

 

[danyra]

8 minutes ago, ronjonp said:

(entmakex (list '(0 . "line") (cons 10 p1) (cons 11 p2) '(62 . 2)))

Ok, its works, thanks you both. 

But, how can I change to a blue color now?

[danyra]

26 minutes ago, rkmcswain said:

(list     (cons 0 "LINE")     (cons 8 "0")     (cons 62 2)     (cons 10 p1)     (cons 11 p2)   ) )

Thank you a lot, can you explain me how its works? what does each of those numbers mean?

Becaause I have a lot of lines and they have different colors, for example blue.

[ronjonp]

21 minutes ago, danyra said:

Ok, its works, thanks you both. 

But, how can I change to a blue color now?

The '(62 . #) is the index color. Make this change for blue: '(62 . 5)

Edited December 2, 2019 by ronjonp

[danyra]

5 minutes ago, ronjonp said:

The '(62 . #) is the index color. Make this change for blue: '(62 . 5)

ok thanks you, I get it 

[ronjonp]

38 minutes ago, danyra said:

ok thanks you, I get it 

Glad to help

 

You could use something like this to be able to choose your color before drawing the line:

(defun c:foo (/ c p1)
  (if (and (setq c (acad_colordlg 1)) (setq p1 (getpoint "\nPunto Inicial:")))
    (entmakex (list '(0 . "line") (cons 10 p1) (cons 11 (polar p1 (* 1.5 pi) 0.18)) (cons 62 c)))
  )
  (princ)
)

 

[BIGAL]

A command style version

 

(defun c:foo2 (/ c p1)
  (if (and (setq c (acad_colordlg 1)) (setq p1 (getpoint "\nPunto Inicial:")))
  (progn
  (setq p2 (polar p1 (* 1.5 pi) 0.18))
  (command "line" p1 p2 "")
  (command "chprop" (entlast) "" "c" c "")
  )
  )
  (princ)
)