Modify Existing MLeader/Multileader Style via LISP

[Kagey]

What I am trying to accomplish can be done via the "Multileader Style Manager", but I am trying to do it without user input.

My current goal is to change arrowhead size to 1/8".

I have figured out how to change the arrowhead size of existing MLeaders, and how to change MLeaders over to an existing style (via vla-put-stylename), but neither of these update the definition of the existing style. That means newly created MLeaders will still have the old arrowhead size.

Thanks in advance!

 

 

[Roy_043]

(defun KGA_Sys_Apply (expr varLst / ret)
  (if (not (vl-catch-all-error-p (setq ret (vl-catch-all-apply expr varLst))))
    ret
  )
)

; (ChangeMleaderArrowSize "Standard" 6.0)
(defun ChangeMleaderArrowSize (nme size / dic mainDic stl)
  (setq mainDic (vla-get-dictionaries (vla-get-activedocument (vlax-get-acad-object))))
  (if
    (and
      (setq dic (KGA_Sys_Apply 'vla-item (list mainDic "ACAD_MLEADERSTYLE")))
      (setq stl (KGA_Sys_Apply 'vla-item (list dic nme)))
    )
    (progn
      (vla-put-arrowsize stl size)
      T
    )
  )
)

 

Edited November 22, 2019 by Roy_043