Rectangle from midpoint

[CadFrank]

Hi,

 

I'd like to know if it is possible to create a rectangle from middlepoint as they do in SolidWorks.

 

Regards.

[Tharwat]

Hi Frank,

 

Does it mean that you want to divide a rectangle into four rectangles ?

If not, give an example.

[CadFrank]

Well you know when you use "getcorner" you kinda see the rectangle.

 

So I'd like to see the rectangle crow from the middle.

 

I've already created a Lisp routine that make a rectangle but with no preview of what it look like.

[hanhphuc]

Hi,

 

I'd like to know if it is possible to create a rectangle from middlepoint as they do in SolidWorks.

 

Regards.

(if (not

(Command "polygon" ))

;4 sides & circumcised & half radius?

(Tharwat will help )

); end of if

[rkent]

...

(Tharwat will help )

); end of if

 

+1

 

Great response!

[Tharwat]

@ hanhphuc, I completely forgot about the polygon command

 

Happy to see you posting around.

[Lee Mac]

Consider the following example:

(defun c:crec ( / a b f l p q x z )
   (if (setq p (getpoint "\nSpecify center of rectangle: "))
       (progn
           (setq z (trans '(0 0 1) 1 0 t)
                 f
               (lambda ( a v )
                   (list
                       (mapcar '+ a v)
                       (mapcar '+ a (list (- (car v)) (cadr v)))
                       (mapcar '- a v)
                       (mapcar '+ a (list (car v) (- (cadr v))))
                   )
               )
           )
           (while (= 5 (car (setq q (grread t 13 0))))
               (redraw)
               (setq l (f p (mapcar '- (cadr q) p)))
               (mapcar '(lambda ( a b ) (grdraw a b -1)) (cons (last l) l) l)
           )
           (if (= 3 (car q))
               (entmake
                   (append
                      '(
                           (000 . "LWPOLYLINE")
                           (100 . "AcDbEntity")
                           (100 . "AcDbPolyline")
                           (090 . 4)
                           (070 . 1)
                       )
                       (mapcar '(lambda ( x ) (cons 10 (trans x 1 z))) (f p (mapcar '- (cadr q) p)))
                       (list (cons 210 z))
                   )
               )
           )
       )
   )
   (redraw) (princ)
)

However, the above uses grread, and therefore sacrifices all standard drawing aids (Object Snap, Orthomode, Tracking etc).

[hanhphuc]

thanks Tharwat me too, im happy need you guys here with sharp eyes

 

@ hanhphuc, I completely forgot about the polygon command

 

not yet.. command polygon is easy if square rectangle but not irregular L x W

 

...to create a rectangle from middle point as they do in SolidWorks.

Regards.

 

i dunno solidworks, so i would just subscribe here

[hanhphuc]

WOW!! your coding speed is faster than my reply to Tharwat's post #6

as usual very nice idea Lee

[Lee Mac]

WOW!! your coding speed is faster than my reply to Tharwat's post #6

as usual very nice idea Lee

 

Thanks!

[CadFrank]

However, the above uses grread, and therefore sacrifices all standard drawing aids (Object Snap, Orthomode, Tracking etc).

 

How come you know that much.... what ever we ask, you can code it...

 

Thanks alot

[Lee Mac]

How come you know that much.... what ever we ask, you can code it...

 

I can't yet write a program to make your coffee - I'll keep working on it though

 

You're welcome Frank

[AIberto]

Here have a example.

http://cadtips.cadalyst.com/linear-objects/draw-rectangle-midpoint

[BIGAL]

Hmm draw a 1x1 sq make it a block with the insertion pt in the centre change x & y scale