convex or concave

[francesc]

How to determine if an irregular polygon is convex or concave

with lisp.

Thanks

[Lee Mac]

Test whether each set of three consecutive vertices follow a clockwise or anticlockwise path.

 

For example:

(defun convex-p ( lst )
   (apply '= (mapcar 'LM:clockwise-p lst (cdr lst) (cddr lst)))
)

;; Clockwise-p  -  Lee Mac
;; Returns T if p1,p2,p3 are clockwise oriented

(defun LM:Clockwise-p ( p1 p2 p3 )
   (<  (* (- (car  p2) (car  p1)) (- (cadr p3) (cadr p1)))
       (* (- (cadr p2) (cadr p1)) (- (car  p3) (car  p1)))
   )
)

 

Test program:

(defun c:test ( / lst sel )
   (if (setq sel (ssget "_+.:E:S" '((0 . "LWPOLYLINE") (-4 . "&=") (70 . 1))))
       (progn
           (setq lst (mapcar 'cdr (vl-remove-if-not '(lambda ( x ) (= 10 (car x))) (entget (ssname sel 0)))))
           (convex-p (cons (last lst) lst))
       )
   )
)

[francesc]

many thanks for your contribution teacher

[Lee Mac]

You're most welcome francesc.

[GP_]

My ~2 cents, if there aren't collinear points.

 

(defun c:test ( / lst sel R L)
   (if (setq sel (ssget "_+.:E:S" '((0 . "LWPOLYLINE") (-4 . "&=") (70 . 1))))
       (progn
           (setq lst (mapcar 'cdr (vl-remove-if-not '(lambda ( x ) (= 10 (car x))) (entget (ssname sel 0)))))
           (mapcar
              '(lambda ( a b c )
                   (if (minusp (sin (- (angle a c) (angle a b)))) (setq R t) (setq L t))
               )
               lst (append (cdr lst) lst) (append (cddr lst) lst)
           )
           (/= R L)
       )
   )    
)

[francesc]

Good Morning. Executing this routine does not work if the polygon has rounded corners tells me that is not convex . help

[Lee Mac]

Good Morning. Executing this routine does not work if the polygon has rounded corners tells me that is not convex . help

 

Simply include the mid-point of each arc segment in the list of points to be tested.

[francesc]

Lee

 

And this is done as a teacher

[francesc]

No how.

Please I need help on this topic

Many thanks teacher