System variable for "Access Online Content"

[bababarghi]

Hopefully I have created the thread in the right place.

 

I was wondering if there is any system/environment variable to disable accessing online content? (I need to disable this feature via my lisp code)

 

[zaphod]

seem to be different on every version of autocad this might be of some help

http://otb.manusoft.com/2009/03/disable-infocenter-in-autocad-2010.htm

[bababarghi]

Found the answer here.

 

WBHELPONLINE is the undocumented variable name.

 

However that is a Read Only variable.

Edited March 31, 2014 by bababarghi

[RobDraw]

Then it doesn't really answer your question.

 

Does that mean there isn't a variable to control it?

 

Why LISP?

 

Isn't that setting stored in your profile so that once you change it the setting sticks?

[bababarghi]

You are right. Not really addressed my issue.

 

So far, that's the only clue I found in regard to online access permissions.

 

LSP deployment is preferred because I need to push lots of settings to new CAD machines in our office e.g support paths, template paths, printer configs, etc. Disabling online access is also one the items which needs to be applied on new machines.

 

I have a feeling that, at the end of the day, I need to pursuit Registry editing solutions (which is not preferred at all)

[ReMark]

Are you referring to the InfoCenter also called the CommCenter?

[bababarghi]

The intent is to be able to bring up 'offline' help window by pressing F1 key.

[ReMark]

Ahhhh, I see. Now we are getting to the crux of the matter. Clarity provides direction.

[RobDraw]

Granted I don't get much involved with the network stuff and this may be "old school" but don't you have a default profile that can be loaded at any time for setting/resetting paths, variables, etc.?

Edited March 31, 2014 by RobDraw

[BlackBox]

However that is a Read Only variable.

 

Is it now... Give this a try:

 

(vl-load-com)

(defun c:OnlineContentOff ()
 (vl-registry-write
   (strcat
     "HKEY_CURRENT_USER\\"
     (if vlax-user-product-key						; If 2013
(vlax-user-product-key)						; Use 2013 function
(vlax-product-key)						; Use legacy function
     )
     "\\Profiles\\"
     (getvar 'cprofile)
     "\\Variables\\"
   )
   "WBHELPONLINE"
   0
 )
 (alert
   (strcat
     "Online content has been disabled.\n\n"
     "Please restart your session for these changes to take effect. "
   )
 )
 (princ)
)

[BlackBox]

Are you referring to the InfoCenter also called the CommCenter?

 

... And since it is loosely related to this thread:

 

(vl-load-com)

(defun c:InfoCenterOff ()
 (vl-registry-write
   (strcat
     "HKEY_CURRENT_USER\\"
     (if vlax-user-product-key						; If 2013
(vlax-user-product-key)						; Use 2013 function
(vlax-product-key)						; Use legacy function
     )
     "\\InfoCenter"
   )
   "InfoCenterOn"
   0
 )
 (alert
   (strcat
     "InfoCenter has been disabled.\n\n"
     "Please restart your session for these changes to take effect. "
   )
 )
 (princ)
)

[bababarghi]

Works perfectly fine except the the RED coloured bit highlighted at following code. The value should be string

 

Is it now... Give this a try:

 

(vl-load-com)

(defun c:OnlineContentOff ()
 (vl-registry-write
   (strcat
     "HKEY_CURRENT_USER\\"
     (if vlax-user-product-key						; If 2013
(vlax-user-product-key)						; Use 2013 function
(vlax-product-key)						; Use legacy function
     )
     "\\Profiles\\"
     (getvar 'cprofile)
     "\\Variables\\"
   )
   "WBHELPONLINE"
   [color="red"][b]"[/b][/color]0[color="red"][b]"[/b][/color]                  ; [color="red"]<------This line needed a couple of (")[/color]
 )
 (alert
   (strcat
     "Online content has been disabled.\n\n"
     "Please restart your session for these changes to take effect. "
   )
 )
 (princ)
)

[BlackBox]

Strange - in 2014 it appeared to be int(-eger) from RegEdit view. Especially so, given that InfoCenterOff requires same.

 

Guess that's what I get for writing code in the post editor and not testing. LoL

 

In any event, I'm glad you got it sorted, and thank you for the clarification.

 

Cheers