Getting help from the Autocad ActiveX and VBA reference

[Lee Mac]

for example , a specific layer without extracting it out of its collection

 

Since all Layer objects are stored within the Layers Collection, you would inexorably need to retrieve the Layer object from the Collection in order to operate on it, for example, to lock Layer "0":

 

Using Visual LISP:

(if
   (not
       (vl-catch-all-error-p
           (setq lay
               (vl-catch-all-apply 'vla-item
                   (list
                       (vla-get-layers
                           (vla-get-activedocument
                               (vlax-get-acad-object)
                           )
                       )
                       "0"
                   )
               )
           )
       )
   )
   (vla-put-lock lay :vlax-true)
)

Using Vanilla AutoLISP:

(if (setq lay (tblobjname "layer" "0"))
   (progn
       (setq lay (entget lay)
             bit (assoc 70 lay)
       )
       (entmod (subst (cons 70 (logior 4 (cdr bit))) bit lay))
   )
)

Using a combination of Vanilla / Visual:

(if (setq lay (tblobjname "layer" "0"))
   (vla-put-lock (vlax-ename->vla-object lay) :vlax-true)
)