Fillet Radius Lisp

[CivilPrice]

Does anyone have a fillet Radius lisp routine. so instead of typing F(fillet) R(radius) then the radius dimension, I can just type FR, and it will automatically be fillet radius and will work continuously until I exit the command.

 

I am sure someone out there has this.

 

Thank You!

[Nardino]

I don't have a lisp, but if you know how to modify the cui, you can add a new command called say .....FR...., and add this to the macro line of the cui ^C^C_fillet;R;0;; and it will work just fine

[Tharwat]

Hi

The example that was give by Nardino is also correct as well as the following.

 

(defun c:fr (/ radius)
 (setq radius 0.0)
 (command "_.fillet" "_r" radius pause)
 (princ)
 )

 

Regards

Tharwat

[MSasu]

@tharwat313: You may also set the radius for FILLET command by FILLETRAD system variable:

 

(setvar "FILLETRAD" 0)

 

Regards,

[CivilPrice]

AWESOME! im coming straight from LDD 2005, so I have never used the CUI...Yet, i'll try that out first.

 

You guys are quick, tons of thanks!

[Tharwat]

AWESOME! im coming straight from LDD 2005, so I have never used the CUI...Yet, i'll try that out first.

 

You guys are quick, tons of thanks!

 

you're welcome any time .......

[Tharwat]

@tharwat313: You may also set the radius for FILLET command by FILLETRAD system variable:

 

(setvar "FILLETRAD" 0)

 

Regards,

 

I do agree with you ... And thanks for sharing msasu

 

My Best Regards

 

Tharwat

[CivilPrice]

Ok... In the CUI the command shows up, but if I type FR in the command line... nothing. So I used the command alias editor and there was a FilletRad and I set that to FR.

 

It works but I enter a value and it exits the command.

 

in the properties of the cui for my new fillet radius:

 

name: fillet radius

display: FR

macro: ^C^C_fillet;R;0;;

 

what did I do wrong?

[Tharwat]

Ok... In the CUI the command shows up, but if I type FR in the command line... nothing. So I used the command alias editor and there was a FilletRad and I set that to FR.

 

It works but I enter a value and it exits the command.

 

in the properties of the cui for my new fillet radius:

 

name: fillet radius

display: FR

macro: ^C^C_fillet;R;0;;

 

what did I do wrong?

 

There is no need for tow semicolon..... That's all

 

Enjoy

Tharwat

[CivilPrice]

hmm... still doesn't work??? I enter the value... boom ends command???

 

maybe i approched this wrong. i dont want to set a value to fillet radius.

 

i want a new command that is filletradius, then i type the radius, it holds that radius for multiple line until i choose to exit the command.

 

oh i need to try they lisp

[Nardino]

Is your cui like this?

[Tharwat]

Please follow the steps below to get the fruits.

 

1- open the CUI in Autocad.

2- create a new command .

3- in the cell of macro within the command that created type the code

like this c^c^_fillet;r;0;

4-Bring the command which you created to one of the menu bars of Autocad

5- Press Apply then Ok

6- Go to the menu that the command inserted to then invoke the command

7- Enjoy the command

 

Tharwat

[Nardino]

I have no idea why it is not working

[alanjt]

I have a custom Fillet with radius one I use, but I also have these for some common radii that I use...

 

;fillet with set radius
;Alan J. Thompson
(mapcar
 '(lambda (f r)
    (eval (list 'defun
        f
        nil
        (list 'setvar "filletrad" r)
        (list 'princ (strcat "\nFillet radius set to: " (rtos r)))
        (list 'command "_.fillet")
        '(princ)
      )
    )
  )
 '(c:FF    c:F1    c:F15    c:F2    c:F3    c:F4    c:F45    c:F5    c:F6    c:F7    c:F8    c:F9)
 '(0        1    1.5    2    3    4    4.5    5    6    7    8    9)
)

[alanjt]

If all you want to do is fillet with a radius of zero, just hold the shift key down when selecting and it will fillet with a radius of zero, regardless of the set fillet radius.

[Nardino]

many ways of skinning the cad.........i mean cat

[paulmcz]

Here is another way:

 

(defun c:f (/ df e1)
 (setvar "cmdecho" 0)
 (setq sdf (getvar "filletrad"))
 (princ "\n filletrad <  ")
 (princ sdf)
 (princ " > ?? :")
 (setq df (getdist))
 (if (= df nil)
   (setq df sdf)
 )
 (setvar "filletrad" df)
 (setq e1 0)
 (while e1
   (command "fillet"
     (setq e1 (entsel "\n Select first object:"))
     (if e1
       (setq e2 (entsel "\n Select second object:"))
     )
   )
 )
 (princ)
)

[alanjt]

I would avoid selecting the objects to feed to the FILLET command since you will be limited to what you can fillet. With fillet, you can fillet a single polyline vertex, but if you try and select each segment with entsel, it will not work and only prompt you that an item can't be filleted with itself.

[paulmcz]

I would avoid selecting the objects to feed to the FILLET command since you will be limited to what you can fillet. With fillet, you can fillet a single polyline vertex, but if you try and select each segment with entsel, it will not work and only prompt you that an item can't be filleted with itself.

 

You are right. I use this for past 8 years and that's exactly what happens when I accidentally select polyline's 2 segments.

[alanjt]

Hmm, how about this for a repeater...

(defun c:FR (/)
 (vl-load-com)
 (setvar 'filletrad
         (cond ((getdist (strcat "\nSpecify fillet radius <" (rtos (getvar 'filletrad)) ">: ")))
               ((getvar 'filletrad))
         )
 )
 (vla-sendcommand
   (cond (*AcadDoc*)
         ((setq *AcadDoc* (vla-get-activedocument (vlax-get-acad-object))))
   )
   "_.multiple _.fillet "
 )
 (princ)
)