Delete All Dimensions

[pBe]

You can apply it with locked layers?

 

Will omit Dimensions in XRefs and on locked layers

 

not included,wont be process, skip, ignore,....

[Lee Mac]

You can apply it with locked layers?

 

As stated and subsequently reiterated by pBe, not with the current code.

 

To delete Dimensions on locked layers, the layers must first be unlocked, e.g.:

 

(defun c:deldims ( / d l )
   (setq d (vla-get-activedocument (vlax-get-acad-object)))
   (vlax-for a (vla-get-layers d)
       (if (eq :vlax-true (vla-get-lock a))
           (progn
               (vla-put-lock a :vlax-false)
               (setq l (cons a l))
           )
       )
   )
   (vlax-for b (vla-get-blocks d)
       (if (eq :vlax-false (vla-get-isxref b))
           (vlax-for o b
               (if (wcmatch (vla-get-objectname o) "AcDb*Dimension*")
                   (vla-delete o)
               )
           )
       )
   )
   (foreach a l (vla-put-lock a :vlax-true))
   (vla-regen d acallviewports)
   (princ)
)
(vl-load-com) (princ)

[Guest jjorozco]

I see. There are still processes that do not quite understand. Thanks for the advices.