Lisp colour change for all layers and blocks

...

Is there a script that changes xref layer colors?

thanks!

Try it. Change xref layer colors

(defun C:COLORXLAY (/ doc col)
 (vl-load-com)
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vla-startundomark doc)
 (if (setq col (acad_colordlg 7 nil))
   (vlax-for item (vla-get-Layers doc)
     (if (wcmatch (vla-get-name item) "*|*")
(vla-put-color item col)
     )
     )
 ) ;_ end of if
 (vla-endundomark doc)
 (princ)
) ;_ end of d

Thanks VVA, that works quite good!

Would it be hard to add an option to select which xref you want to change?

If you can manage that i will stop begging.

New variant (much longer than the previous )

(defun C:COLORXLAY (/ doc col xreflist ret)
 (vl-load-com)
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vlax-for item (vla-get-Blocks doc)
     (if (= (vla-get-IsXref item) :vlax-true)
        (setq xreflist (cons (vla-get-name item) xreflist))
       )
   )
 (if xreflist
 (if (and (setq ret (_dwgru-get-user-dcl "Select XREF " (acad_strlsort xreflist) t))
          (setq col (acad_colordlg 7 nil))
          )
   (progn
     (setq ret (apply 'strcat (mapcar '(lambda(x)(strcat x "|*,")) ret)))
   (vla-startundomark doc)
   (vlax-for item (vla-get-Layers doc)
     (if (wcmatch (vla-get-name item) ret)
(vla-put-color item col)
     )
     )
       (vla-endundomark doc)
   )
 ) ;_ end of if
   (alert "No XREF Found")
   )
 (princ)
) ;_ end of defun

;;; ************************************************************************
;;; * Library DWGruLispLib Copyright © 2008 DWGru Programmers Group
;;; *
;;; * _dwgru-get-user-dcl (Candidate)
;;; *
;;; * Inquiry of value at the user through a dialogue window
;;; *
;;; *
;;; * 26/01/2008 Version 0002. Edition Vladimir Azarko (VVA)
;;; - the Output on double a clique if the plural choice (multi-nil) is forbidden
;;; - Processing of several columns
;;; * 21/01/2008 Version 0001. Edition Vladimir Azarko (VVA)
(defun _DWGRU-GET-USER-DCL (ZAGL        INFO-LIST   MULTI
                           /           FL          RET
                           DCL_ID      MAXROW      MAX_COUNT_COL
                           COUNT_COL   I           LISTBOX_HEIGHT
                           LST         _LOC_FINISH _LOC_CLEAR
                           NCOL
                          )
;| 
* Inquiry of value at the user through a dialogue window
* Dialogue is formed to "strike"
* the Quantity of lines on page without scrolling is set by variable MAXROW.
* It is necessary to remember, that number MAXROW increases on 3.
* the Maximum quantity of columns is set by variable MAX_COUNT_COL
* It is published
    http://dwg.ru/f/showthread.php?p=203746#post203746
* Parameters of a call:
   zagl - heading of a window [string]
   info-list - the list of line values [List of String]
   multi - t - the plural choice is resolved, nil-is not present
     
* Returns:
The list of the chosen lines or nil - a cancelling
* the Example
(_dwgru-get-user-dcl " Specify a variant " ' ("First" "Second" "Third") nil); _-> ("First") 
(_dwgru-get-user-dcl " Specify a variant " ' ("First" "Second" "Third") t); _-> ("First"  "Second ")
(_dwgru-get-user-dcl " Specify a variant "
  (progn (setq i 0 lst nil) (repeat 205 (setq lst (cons (strcat "Value-" (itoa (setq i (1 + i)))) lst))) (reverse lst)) nil)
(_dwgru-get-user-dcl " Specify a variant, using CTRL and SHIFT for a choice "
  (progn (setq i 0 lst nil) (repeat 205 (setq lst (cons (strcat "Value-" (itoa (setq i (1 + i)))) lst))) (reverse lst)) t)
|;
 (setq MAXROW 40) ;_  max lines without scrolling (To it 3 more lines further will be added)
 (setq MAX_COUNT_COL 5) ; _ a maximum quantity of columns
;;============== Local functions START========================

 (defun _LOC_FINISH ()
   (setq I   0
         RET NIL
   ) ;_ end ofsetq
   (repeat COUNT_COL
     (setq I (1+ I))
     (setq RET (cons (cons I (get_tile (strcat "info" (itoa I)))) RET))
   ) ;_ end ofrepeat
   (setq RET (reverse RET))
   (done_dialog 1)
 ) ;_ end ofdefun
 (defun _LOC_CLEAR (NOMER)
   (setq I 0)
   (repeat COUNT_COL
     (setq I (1+ I))
     (if (/= I NOMER)
       (progn
         (start_list (strcat "info" (itoa I)))
         (mapcar 'add_list (nth (1- I) LST))
         (end_list)
       ) ;_ end ofprogn
     ) ;_ end ofif
   ) ;_ end ofrepeat
 ) ;_ end ofdefun

;;;==================== Local functions END ==================================
;;;==================== MAIN PART ===============================================
 (if (null ZAGL)(setq ZAGL "Select")) ;_ end if
 (if (zerop (rem (length INFO-LIST) MAXROW))
   (setq COUNT_COL (/ (length INFO-LIST) MAXROW))
   (setq COUNT_COL (1+ (fix (/ (length INFO-LIST) MAXROW 1.0))))
 ) ;_ end ofif
 (if (> COUNT_COL MAX_COUNT_COL)
   (setq COUNT_COL MAX_COUNT_COL)
 )
 (setq LISTBOX_HEIGHT (+ 3 MAXROW))
  ;_ We add 3 lines for appearance and for exception boundary scroll
 (if (and (= COUNT_COL 1) (<= (length INFO-LIST) MAXROW))
   (setq LISTBOX_HEIGHT (+ 3 (length INFO-LIST)))
 ) ;_ end ofif
 (setq I 0)
 (setq FL (vl-filename-mktemp "dwgru" NIL ".dcl"))
 (setq RET (open FL "w")
       LST NIL
 ) ;_ end ofsetq
 (mapcar '(lambda (X) (write-line X RET))
         (append (list "dwgru_get_user : dialog { "
                       (strcat "label=\"" ZAGL "\";")
                       ": boxed_row {"
                       "label = \"Value\";"
                 ) ;_ end oflist
                 (repeat COUNT_COL
                   (setq LST
                          (append
                            LST
                            (list
                              " :list_box {"
                              "alignment=top ;"
                              (if MULTI
                                "multiple_select = true ;"
                                "multiple_select = false ;"
                              ) ;_ end ofif
                              "width=31 ;"
                              (strcat "height= " (itoa LISTBOX_HEIGHT) " ;")
                              "is_tab_stop = false ;"
                              (strcat "key = \"info" (itoa (setq I (1+ I))) "\";}")
                            ) ;_ end oflist
                          ) ;_ end ofappend
                   ) ;_ end ofsetq
                 ) ;_ end ofrepeat
                 (list
                   "}"
                   ":row{"
                   "ok_cancel_err;}}"
                 ) ;_ end oflist
         ) ;_ end of list
 ) ;_ end of mapcar
 (setq RET (close RET))
 (if (and (null (minusp (setq DCL_ID (load_dialog FL))))
          (new_dialog "dwgru_get_user" DCL_ID)
     ) ;_ end and
   (progn
     (setq LST INFO-LIST)
     ((lambda (/ RET1 BUF ITM)

        (repeat (1- COUNT_COL)
          (setq I '-1)
          (while (and (setq ITM (car LST))
                      (< (setq I (1+ I)) MAXROW)
                 ) ;_ end of and
            (setq BUF (cons ITM BUF)
                  LST (cdr LST)
            ) ;_ end of setq
          ) ;_ end ofwhile
          (setq RET1 (cons (reverse BUF) RET1)
                BUF  NIL
          ) ;_ end of setq
        ) ;_ end of repeat
        (setq RET RET1)
      ) ;_ end of lambda
     )
     (if LST
       (setq RET (cons LST RET))
     ) ;_ end ofif
     (setq LST (reverse RET))
     (setq I 0)
     (mapcar '(lambda (THIS_LIST)
                (if (<= (setq I (1+ I)) COUNT_COL)
                  (progn
                    (start_list (strcat "info" (itoa I)))
                    (mapcar 'add_list THIS_LIST)
                    (end_list)
                  ) ;_ end ofprogn
                ) ;_ end ofif
              ) ;_ end oflambda
             LST
     ) ;_ end ofmapcar

     (set_tile "info1" "0")
     (setq I 0
           NCOL 1
     ) ;_ end ofsetq
     (repeat COUNT_COL
       (action_tile
         (strcat "info" (itoa (setq I (1+ I))))
         (strcat "(progn (setq Ncol "
                 (itoa I)
                 ")(if (not multi)(_loc_clear Ncol))"
                 "(if (and (not multi)(= $reason 4))(_loc_finish)))"
         ) ;_ end ofstrcat
       ) ;_ end ofaction_tile
     ) ;_ end ofrepeat
     (action_tile "cancel" "(done_dialog 0)")
     (action_tile "accept" "(_loc_finish)")
     (if MULTI
       (set_tile "error" "Use CTRL and SHIFT for a choicet") ;_ end ofset_tile
       (set_tile "error" "It is possible to choose double click") ;_ end ofset_tile
     ) ;_ end ofif
     (if (zerop (start_dialog))
       (setq RET NIL)
       (progn
         (setq
           RET (apply
                 'append
                 (mapcar
                   '(lambda (ITM)
                      (setq THIS_LIST (nth (1- (car ITM)) LST))
                      (mapcar
                        (function (lambda (NUM) (nth NUM THIS_LIST)))
                        (read (strcat "(" (cdr ITM) ")"))
                      ) ;_ end ofmapcar
                    ) ;_ end oflambda
                   RET
                 ) ;_ end ofmapcar
               ) ;_ end ofapply
         ) ;_ end ofsetq

       ) ;_ end ofprogn
     ) ;_ end if
     (unload_dialog DCL_ID)
   ) ;_ end of progn
 ) ;_ end of if
 (vl-file-delete FL)
 RET
) ;_ end ofdefun

WOW!

Thank you so much VVA, this is exactly what we need here, unfortunately nobody here knows how to write lisps .

If i can do something for you let me know, hint: i'm quite good with dynamic blocks.

спасибо !!

OK VVA, 1 more request and i will stop bothering you, really!... maybe

I tried to find it myself looking at the code of the colorx lisp, but it's a bit like chinese for me.

I need to be able to exclude colors 250,251,252,253,254 and 255 from the layer selection or maybe exclude locked layers if that's simpler.

I looked at the code and i think this:

(setq ret (apply 'strcat (mapcar '(lambda(x)(strcat x "|*,")) ret)))

is the line for layer selection, is that right?

Right. keep the new version. The main highlighted in red. Need a function _dwgru-get-user-dcl of the previous (#43) post

(defun C:COLORXLAY1 (/ doc col xreflist ret ignorecolor)
 (vl-load-com)
 [color="Red"](setq ignorecolor '(250 251 252 253 254 255))[/color]
 (setq doc (vla-get-activedocument (vlax-get-acad-object)))
 (vlax-for item (vla-get-Blocks doc)
     (if (= (vla-get-IsXref item) :vlax-true)
        (setq xreflist (cons (vla-get-name item) xreflist))
       )
   )
 (if xreflist ;;; If exist XREF
     (if (and ;;;get xref name and color
           (setq ret (_dwgru-get-user-dcl "Select XREF " (acad_strlsort xreflist) t))
           (setq col (acad_colordlg 7 nil))
          )
   (progn
     (setq ret (apply 'strcat (mapcar '(lambda(x)(strcat x "|*,")) ret)))
   (vla-startundomark doc)
   (vlax-for item (vla-get-Layers doc)
     (if (and (wcmatch (vla-get-name item) ret) ;;; same mask xref
              [color="#ff0000"](not(member(vla-get-color item) ignorecolor))[/color]
              )
(vla-put-color item col)
     )
     )
       (vla-endundomark doc)
   )
 ) ;_ end of if
   (alert "No XREF Found")
   )
 (princ)
) ;_ end of defun

Yes! it works great, thanks again VVA

thanks for color

This Lisp does not change xref. If you want to change xref, open it and use ColorX.

Hello VVA,

I saw your lisp that change the colour of object. Do you have any idea about a lisp for keeping the same colour of objects ? At first the objects have a colour by layer, and after moving them in another layer have the same colour, but this time not by layer. I mean, if i move an object from layer 1, where this object has "by layer" colour (red, let's say) in layer 2, the object will have also red colour, but this time the colour will not be defined "by layer". Thanks!

Specify clearly the object of the same color, which has a layer on which it is located

(defun C:COLORFL ( / adoc blocks color ent lays)
 ;;;Color From Layer
   (setq adoc  (vla-get-activedocument (vlax-get-acad-object))
         lays  (vla-get-layers adoc)
   )
   (setvar "errno" 0)
   (vla-startundomark adoc)
   (while (and (not (vl-catch-all-error-p
                                   (setq ent (vl-catch-all-apply
                                                 (function nentsel)
                                                 '("\nSelect entity <Exit>:")
                                             )
                                   )
                               )
                          )
                          (/= 52 (getvar "errno"))
                     )
                  (if ent
                      (progn (setq ent (vlax-ename->vla-object (car ent))
                                   lay (vla-item lays (vla-get-layer ent))
                                   color (vla-get-color lay)
                             )
                             (if (= (vla-get-lock lay) :vlax-true)
                                 (progn (setq layloc (cons lay layloc))
                                        (vla-put-lock lay :vlax-false)
                                 )
                             )
                             (vl-catch-all-apply (function vla-put-color) (list ent color))
                             (vla-regen adoc acallviewports)
                      )
                      (princ "\nNothing selection! Try again.")
                  )
              )
              (foreach i layloc (vla-put-lock i :vlax-true))
              (vla-endundomark adoc)
   (princ)
 )

Lisp from #50 can change color of nested objects

Thanks VVA, your lisp is perfect. My english is bad, sorry for that.

Only one thing: can this lisp work if i want to select many object at a time? Or only one object at a time?

I want to work this way: copy all the object in a drawing, and change the colour for all new objects (copied) with this lips, and put them in a new layer. This is why i want to select many objects when i use this lisp.

Thanks!

Thanks VVA, your lisp is perfect. My english is bad, sorry for that.

My english is bad too.

I want to work this way: copy all the object in a drawing, and change the colour for all new objects (copied) with this lips, and put them in a new layer. This is why i want to select many objects when i use this lisp.

Thanks!

(defun C:COLORFL ( / adoc blocks color ent lays ss i)
 ;;;Color From Layer
 (vl-load-com)
   (setq adoc  (vla-get-activedocument (vlax-get-acad-object))
         lays  (vla-get-layers adoc)
   )
   (setvar "errno" 0)
   (vla-startundomark adoc)
  (vl-catch-all-apply
  '(lambda ()
   (while (setq ss (ssget "_:L"))
     (setq i '-1)
     (repeat (sslength ss)
       (setq ent (vlax-ename->vla-object (ssname ss (setq i (1+ i))))
             lay (vla-item lays (vla-get-layer ent))
             color (vla-get-color lay)
             )
       (if (= (vla-get-lock lay) :vlax-true)
         (progn (setq layloc (cons lay layloc))
           (vla-put-lock lay :vlax-false)
           )
         )
       (vl-catch-all-apply (function vla-put-color) (list ent color))
       )
     )
     )
  )
     (foreach i layloc (vla-put-lock i :vlax-true))
    (vla-endundomark adoc)
   (princ)
 )

Thanks VVA, it's ok!

Is it possible to do the same thing with linetyle, linetypescale and line weight? Thanks!

(defun C:PFL (/ adoc blocks color ent lays ss i linetype lineweight)
;;;Properties From Layer
 (vl-load-com)
 (setq adoc (vla-get-activedocument (vlax-get-acad-object))
       lays (vla-get-layers adoc)
 ) ;_ end of setq
 (setvar "errno" 0)
 (vla-startundomark adoc)
 (vl-catch-all-apply
   '(lambda ()
      (while (setq ss (ssget "_:L"))
        (setq i '-1)
        (repeat (sslength ss)
          (setq ent        (vlax-ename->vla-object (ssname ss (setq i (1+ i))))
                lay        (vla-item lays (vla-get-layer ent))
                color      (vla-get-color lay)
                linetype   (vla-get-linetype lay)
                lineweight (vla-get-lineweight lay)
          ) ;_ end of setq

          (if (= (vla-get-lock lay) :vlax-true)
            (progn (setq layloc (cons lay layloc))
                   (vla-put-lock lay :vlax-false)
            ) ;_ end of progn
          ) ;_ end of if
          (vl-catch-all-apply
            '(lambda ()
               (vla-put-color ent color)
               (vla-put-linetype ent linetype)
               (vla-put-lineweight ent lineweight)
             ) ;_ end of lambda
          ) ;_ end of vl-catch-all-apply
        ) ;_ end of repeat
      ) ;_ end of while
    ) ;_ end of lambda
 ) ;_ end of vl-catch-all-apply
 (foreach i layloc (vla-put-lock i :vlax-true))
 (vla-endundomark adoc)
 (princ)
) ;_ end of defun

It's perfect! Thanks!

Something more....

One circle is in layer 1 , this layer has 0,5 lineweight. Actual circle's lineweight is 2 , is not "by layer". Using the lisp, circle's lineweight change back to 0,5.

For me will be ok if, after using the lisp for all objects in a drawing and moving all the objects in a new layer, i will see no changes as colour, linetype, lineweight or linetype scale. I mean, all the objects will look like initial, no matter which layer they are moved in. Is is possible? Thanks!

Try it

(defun C:PFL (/ adoc blocks  ent lays ss i color linetype lineweight *error*)
;;;Properties From Layer
   (defun *error* (msg)
   (setvar "MODEMACRO" "")
   (princ msg)
   (vla-regen aDOC acactiveviewport)
   (bg:progress-clear)
   (bg:layer-status-restore)
   (princ)
 ) ;_ end of defun

 (vl-load-com)
 (command "_.UNDO" "_Mark")
 (setvar "CLAYER" "0")
 (pfl)
 (command "_.Regenall")
 (princ "\n*** Command _.UNDO _Back restore previous settings")
 (princ)
 ) ;_ end of defun
(defun pfl ( / layer-list aDOC count  *error* color linetype lineweight lays count)
 (defun *error* (msg)
   (setvar "MODEMACRO" "")
   (princ msg)
   (vla-regen aDOC acactiveviewport)
   (bg:progress-clear)
   (bg:layer-status-restore)
   (princ)
 ) ;_ end of defun
 (defun _loc_fun ()
   (if	(= (vla-get-IsXref Blk) :vlax-false)
     (progn
(setq count 0)
(if (> (vla-get-count Blk) 100)
  (bg:progress-init
    (strcat (vla-get-name Blk) " :")
    (vla-get-count Blk)
  ) ;_ end of bg:progress-init
  (progn
    (setvar "MODEMACRO" (vla-get-name Blk))
  ) ;_ end of progn
) ;_ end of if
(vlax-for Obj Blk
         (setq lay        (vla-item lays (vla-get-layer Obj))
                color      (vla-get-color lay)
                linetype   (vla-get-linetype lay)
                lineweight (vla-get-lineweight lay)
          ) ;_ end of setq
         (bg:progress (setq count (1+ count)))
         (vl-catch-all-apply
            '(lambda ()
               (if (eq (vla-get-color Obj) acByLayer)(vla-put-color Obj color))
               (if (eq (vla-get-linetype Obj) "ByLayer") (vla-put-linetype Obj linetype))
               (if (eq (vla-get-lineweight Obj) acLnWtByLayer)(vla-put-lineweight Obj lineweight))
             ) ;_ end of lambda
          ) ;_ end of vl-catch-all-apply
         ) ;_ end of vlax-for
(bg:progress-clear)
     ) ;_ end of progn
   ) ;_ end of if
 ) ;_ end of defun
 (setq	aDOC	   (vla-get-activedocument (vlax-get-acad-object))
       lays (vla-get-layers adoc)
 ) ;_ end of setq
;;;  (grtext -1 "Stage 1. Viewing of layers")
 (bg:layer-status-save)
 (vlax-for Blk (vla-get-Blocks aDOC)
   (if (eq (vla-get-IsLayout Blk) :vlax-true)
     (_loc_fun)))
 (bg:layer-status-restore)
;;;  ???????
 (setq *PD_LAYER_LST* nil)
)
(defun bg:progress-clear ()
 (setq *BG:PROGRESS:MSG* nil)
 (setq *BG:PROGRESS:MAXLEN* nil)
 (setq *BG:PROGRESS:LPS* nil)
 (setvar "MODEMACRO" (vl-princ-to-string *BG:PROGRESS:OM*))
 ;;;(vla-regen (vla-get-activedocument (vlax-get-acad-object)) acactiveviewport)
 (princ)
 )
(defun bg:progress-init (msg maxlen)
 ;;; msg - message
 ;;; maxlen - max count
 (setq *BG:PROGRESS:OM* (getvar "MODEMACRO"))
 (setq *BG:PROGRESS:MSG* (vl-princ-to-string msg))
 (setq *BG:PROGRESS:MAXLEN* maxlen)
 (setq *BG:PROGRESS:LPS* '-1)(princ)
 )
(defun bg:progress ( currvalue / persent str1 count)
 (if *BG:PROGRESS:MAXLEN*
   (progn
 (setq persent (fix (/ currvalue 0.01 *BG:PROGRESS:MAXLEN*)))
 ;;;Every 5 %
 (setq count (fix(* persent 0.2)))
 (setq str1 "")
 (if (/= count *BG:PROGRESS:LPS*)
   (progn
     ;;(setq str1 "")
     (repeat persent (setq str1 (strcat str1 "|")))
     )
   )
      ;;; currvalue - current value
     (setvar "MODEMACRO"
             (strcat (vl-princ-to-string *BG:PROGRESS:MSG*)
                     " "
                     (itoa persent)
                     " % "
                     str1
                     )
             )
     (setq *BG:PROGRESS:LPS* persent)
 )
   )
 )
(defun bg:layer-status-restore ()
   (foreach item *PD_LAYER_LST*
     (if (not (vlax-erased-p (car item)))
       (vl-catch-all-apply
         '(lambda ()
            (vla-put-lock (car item) (cdr (assoc "lock" (cdr item))))
            (vla-put-freeze (car item) (cdr (assoc "freeze" (cdr item))))
            ) ;_ end of lambda
         ) ;_ end of vl-catch-all-apply
       ) ;_ end of if
     ) ;_ end of foreach
   (setq *PD_LAYER_LST* nil)
   ) ;_ end of defun

 (defun bg:layer-status-save ()
   (setq *PD_LAYER_LST* nil)
   (vlax-for item (vla-get-layers (vla-get-activedocument (vlax-get-acad-object)))
     (setq *PD_LAYER_LST* (cons (list item
                                 (cons "freeze" (vla-get-freeze item))
                                 (cons "lock" (vla-get-lock item))
                                 ) ;_ end of cons
                           *PD_LAYER_LST*
                           ) ;_ end of cons
           ) ;_ end of setq
     (vla-put-lock item :vlax-false)
     (if (= (vla-get-freeze item) :vlax-true)
     (vl-catch-all-apply '(lambda () (vla-put-freeze item :vlax-false))))
     ) ;_ end of vlax-for
   ) ;_ end of defun

This last lisp is exaclty what I wanted. Thanks!

Is it possible to save changes to xref colors?

John

Command:

ColorX - change color all object of drawing. All layer unlock and thaw

ColorXREF change color xref only on a current session. All layer unlock and thaw

ColorXL - change color all object of drawing. Objects on the locked and frozen layers are ignored

ColorXREFL change color xref only on a current session. Objects on the locked and frozen layers are ignored

*** Add 20.03.2009 - Now ColorX ColorXREF work with Attrubutes

*** Add 31.03.2009 - Now ColorX and ColorXREF colored dimension (include radius).

*** Add 02.04.2009 - Change color Qleader, Mtext, Mleader. Add Simple progressbar

 

If you want to operate colour of xref objects in the blanket drawing:

1. Open Xref (sourcing drawing.dwg)

2. Run ColorX and set color bylayer

3.open a blanket drawing

4. Creat layer "Xref"

5. Set layer "Xref" current

6 use xref command to attach the source drawing (sourcing drawing.dwg)

7.change the xref color in layer manager. choose grey

NOTE. If some objects in xref (sourcing drawing.dwg) are placed on a layer 0 your mast change layer of an insert of the external reference in a blanket drawing to grey too. (layer "XREF")

I do not know as this technical term sounds in English. I translate from Russian: there Is an emersion of a layer 0. All objects located on 0 layer in drawing of the external reference (sourcing drawing.dwg) inherit properties of a external reference layer in blanket drawing (layer "XREF")

Is it possible to save the layer color status when exit?

Command:

ColorX - change color all object of drawing. All layer unlock and thaw

ColorXREF change color xref only on a current session. All layer unlock and thaw

ColorXL - change color all object of drawing. Objects on the locked and frozen layers are ignored

ColorXREFL change color xref only on a current session. Objects on the locked and frozen layers are ignored

*** Add 20.03.2009 - Now ColorX ColorXREF work with Attrubutes

*** Add 31.03.2009 - Now ColorX and ColorXREF colored dimension (include radius).

*** Add 02.04.2009 - Change color Qleader, Mtext, Mleader. Add Simple progressbar

 

If you want to operate colour of xref objects in the blanket drawing:

1. Open Xref (sourcing drawing.dwg)

2. Run ColorX and set color bylayer

3.open a blanket drawing

4. Creat layer "Xref"

5. Set layer "Xref" current

6 use xref command to attach the source drawing (sourcing drawing.dwg)

7.change the xref color in layer manager. choose grey

NOTE. If some objects in xref (sourcing drawing.dwg) are placed on a layer 0 your mast change layer of an insert of the external reference in a blanket drawing to grey too. (layer "XREF")

I do not know as this technical term sounds in English. I translate from Russian: there Is an emersion of a layer 0. All objects located on 0 layer in drawing of the external reference (sourcing drawing.dwg) inherit properties of a external reference layer in blanket drawing (layer "XREF")