lisp routine to automate coordinates

Hi, anybody who has the lisp routine that can generate drawing COORDINATES automaticaly, instead of typing ID at the command prompt & taking ID one by one.

jake

Here is a little routine to write coordinates to the drawing.

Very simple and no error checking, but it works for me

Load and type WC

;WC.LSP is a programme to write coordinates. eldon Nov 1999
(defun C:WC (/ pt0 e east eastin n north northin)
;here begins the loop that gets the actual positions
  (while (setq pt0 (getpoint "\nPick co-ordinate point:  "))
         (setq e (car pt0)        ;easting coord as number
               n (cadr pt0)       ;northing coord as number
               east (rtos e 2 3)  ;easting coord as string
               north (rtos n 2 3)  ;northing coord as string
               eastin (strcat  east "mE" )
               northin (strcat  north "mN")
         )
  (command "TEXT" pt0 "0.5" "0" eastin);size of text changed manually
  (command "TEXT" "" northin)
   )
   (princ)
)

thank you for your reply.....it really help me a lot.

hey, without LISP i can help you... in my company we use "field" command for coordinates.. we just have to create 1 field and copy copy copy to whichever or wherever you want to know the coordinates and then command the regenerate to refresh the fields.. maybe somebody here can make a code for automatic putting of fields instead of just plain text so when you move the reference point the coordinates will also change...

sorry i'm still new to LISP.. so i can't post my own codes...

Two more:

http://www.asmitools.com/Files/Lisps/Ordi.html

http://www.asmitools.com/Files/Lisps/Ordy.html

ASMI, this is exactly what i'm looking for... thanks a lot.

nice one..it really helps....big thanks ASMI

ASMI

Refer to ordy.lsp could be the coordenate ID and X,Y in a table

Two more:

http://www.asmitools.com/Files/Lisps/Ordi.html

http://www.asmitools.com/Files/Lisps/Ordy.html

Merry Christmas and best wishes to you for a successful New Year 2010.

hello all,

i am wondering if the lisp routine that eldon posted above, could be modified to select multiple points and place the x,y beside each point?? is this possible??

any help would be appreciated

Emily

Hi Emily,

Hows this?

(defun c:txtpt (/ Make_MText i ss ent)
 ; Lee Mac  ~  21.01.10

 (defun Make_MText (pt str)
   (entmakex (list (cons 0 "MTEXT")
                   (cons 100 "AcDbEntity")
                   (cons 100 "AcDbMText")  (cons 10 pt) (cons 1 str))))

 (if (setq i -1 ss (ssget '((0 . "POINT"))))
   (while (setq ent (ssname ss (setq i (1+ i))))
     (Make_MText (cdr (assoc 10 (entget ent)))
       (apply (function strcat)
         (mapcar (function strcat) '("X = " "\nY = ")
           (mapcar (function rtos) (cdr (assoc 10 (entget ent)))))))))

 (princ))

Hi Emily,

 

Hows this?

 

(defun c:txtpt (/ Make_MText i ss ent)
 ; Lee Mac  ~  21.01.10

 (defun Make_MText (pt str)
   (entmakex (list (cons 0 "MTEXT")
                   (cons 100 "AcDbEntity")
                   (cons 100 "AcDbMText")  (cons 10 pt) (cons 1 str))))

 (if (setq i -1 ss (ssget '((0 . "POINT"))))
   (while (setq ent (ssname ss (setq i (1+ i))))
     (Make_MText (cdr (assoc 10 (entget ent)))
       (apply (function strcat)
         (mapcar (function strcat) '("X = " "\nY = ")
           (mapcar (function rtos) (cdr (assoc 10 (entget ent)))))))))

 (princ))

absolutely perfect,

thanx so much Lee Mac exactly what i was after:D:D

You're welcome

Tools --> Data Extraction